Habituation example - word-object pairings

About this protocol

This protocol is based on Experiment 3 of the classic Werker et al. (1998) study cited below. Infants are habituated to a single word-object pair. Later, they are presented with four test items: familiar object with familiar word, familiar object with novel word, novel object with familiar word, and novel object with novel word. Pre-test and post-test trials, consisting of a novel object and word that do not appear in any other trials, are also included.

Werker, J. F., Cohen, L. B., Lloyd, V. L., Casasola, M., & Stager, C. L. (1998). Acquisition of word–object associations by 14-month-old infants. Developmental psychology, 34(6), 1289.

Starting the protocol

Starting definitions

This protocol will use one central display and a light positioned directly below the display. These would be our minimal starting definitions:

SIDES ARE {CENTER}
DISPLAYS ARE {CENTER}
LIGHTS ARE {CENTER}

However, if you have more lights connected in your system (e.g. for headturn preference procedure) and will be leaving them all connected during testing, you may need to define more lights so that you can identify which one should be CENTER.

SIDES ARE {CENTER, RIGHT, LEFT}
DISPLAYS ARE {CENTER}
LIGHTS ARE {LEFT, CENTER, RIGHT}

Tags

Now we'll define our tags that reference files. We have three audio files and three video files - two of each for use in habituation/test trials, and one of each reserved for pre-test and post-test.

We could define these with LET statements. But because these will always be paired, it is convenient to use TYPEDLET. This will allow us to define all of our possible word-object pairings and randomly select a pair for presentation, rather than independently selecting audio and video, and having less control over which appear together.

Our videos, which we'll call round, green, and blue, show toys being rotated by a hand on a black background. Our audio files consist of infant-directed repetitions of a nonword: deeb, geff, or mip.

TYPEDLET audio deeb = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\deeb.wav"
TYPEDLET audio geff = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\geff.wav"
TYPEDLET audio mip = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\mip.wav"
TYPEDLET video blue = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\blue.mp4"
TYPEDLET video green = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\green.mp4"
TYPEDLET video round = "C:\Users\ldev\Desktop\BITTSy\HabitExample\stim\round.mp4"

Having defined these tags with TYPEDLET, we can use LINKED to define tags that pair them up appropriately. The tags mip and round will be reserved for pre-test and post-test, but all other pairings will occur in the test phase, and one of them will be featured in the habituation phase.

LINKED prepost = {mip, round}
LINKED deeb_blue = {deeb, blue}
LINKED deeb_green = {deeb, green}
LINKED geff_blue = {geff, blue}
LINKED geff_green = {geff, green}

Groups

We'll define two groups consisting of our LINKED tags. Both will contain all of the possible pairings of deeb, geff, blue, and green. At the start of each test session, we will randomly select one pairing from the first group for the infant to see during habituation. The test phase for all infants will consist of all four pairings, so our test_trials group will also contain all four.

LET habit_pairs = {deeb_blue, deeb_green, geff_blue, geff_green}
LET test_trials = {deeb_blue, deeb_green, geff_blue, geff_green}

Experiment settings

Now we define our experiment settings. Because this protocol has a habituation phase, we must define all of our habituation criteria here.

DEFINE WINDOWSIZE 3
DEFINE WINDOWOVERLAP NO
DEFINE CRITERIONREDUCTION 0.65
DEFINE BASISCHOSEN FIRST
DEFINE WINDOWTYPE FIXED

We could also define key assignments for live-coding - without them, experimenters will use C for looks CENTER to the light/screen, and W for AWAY.

STEPS for execution

Pre-test

Now for the STEPs that will start once we run the protocol. First, we'll define our pre-trial phase. Before each trial, we'll have a center light flash until the infant is paying attention. We'll have the experimenter press C to begin a CENTER look.

STEP 1
Phase Pretrial Start

STEP 2
LIGHT CENTER BLINK 250
UNTIL KEY C

Once the infant is looking, we can start a trial. We'll turn off the light and display the pre-test stimuli. Note that because we defined the LINKED tag prepost with both an audio tag component and a video tag component, we can reference the LINKED tag in the action statements for both AUDIO and VIDEO.

STEP 3
LIGHT CENTER OFF
Trial Start

STEP 4
VIDEO CENTER prepost LOOP
AUDIO CENTER prepost LOOP
UNTIL SINGLELOOKAWAY prepost GREATERTHAN 1000
UNTIL TIME 14000

STEP 5
Trial End
VIDEO CENTER OFF
AUDIO CENTER OFF

STEP 6
Phase End

Our trials throughout the experiment will last a maximum of 14 seconds. Trials will end when we reach this limit, or when the infant is recorded as looking away for at least 1 second. There is only one pre-test trial, so once it is over, we end the phase and move on to habituation.

Habituation

As we start the habituation phase, the first thing we need to do is assign the participant randomly to a word-object pair that they will see during habituation. There were four possibilities in the habit_pairs group.

STEP 7
Phase Habituation Start
LET pair = (FROM habit_pairs RANDOM)

Having selected in advance which word-object pair the participant will see, we can define the inter-trial period (with the blinking light) and a habituation trial. Note that the pair tag we selected from habit_pairs is again a LINKED tag that can be referenced in both of the action statements to play the audio and video.

STEP 8
LIGHT CENTER BLINK 250
UNTIL KEY C

STEP 9
LIGHT CENTER OFF
Trial Start

STEP 10
VIDEO CENTER pair LOOP
AUDIO CENTER pair LOOP
UNTIL SINGLELOOKAWAY pair GREATERTHAN 1000
UNTIL TIME 20000

STEP 11
Trial End
VIDEO CENTER OFF
AUDIO CENTER OFF

We'll play the exact same stimuli for the rest of our habituation trials, so now we'll define a loop. We want to either keep playing trials until the infant meets our habituation criteria or reaches the maximum of 20 habituation trials (19 of them via the loop).

STEP 12
LOOP STEP 8
UNTIL 19 TIMES
UNTIL CRITERIONMET

STEP 13
Phase End

Note that our loop goes back to STEP 8, where we started the light blinking for the inter-trial period, but excludes the assignment of the dynamic tag pair back in STEP 7. This is why we chose which word-object pair would be presented before we needed to use it to display trial stimuli in STEP 10: we didn't want this LET statement to be included in the loop. We want this dynamic tag to be assigned as one pair and stay that way so that we are repeatedly presenting the same word-object pair. If the LET statement were inside the loop steps, we would repeat the choose statement on every loop iteration, and we would show different word-object pairings on different trials. In general, when you want to select from a group and be able to refer to the result of that selection throughout a phase, it's a good practice to make that selection in the same STEP where you define your phase's start. "Getting it out of the way" like this makes it easier to not accidentally loop over and reassign a dynamic tag that you would prefer to stay static.

Test phase

Once the infant has habituated or met the maximum number of trials, we move on to the test phase. We'll begin again with the inter-trial light flashing before beginning a trial.

STEP 14
Phase Test Start

STEP 15
LIGHT CENTER BLINK 250
UNTIL KEY C

STEP 16
LIGHT CENTER OFF
Trial Start

Recall that our four test items are all in the test_trials group, and are LINKED tags with all the possible pairings of the audio deeband geff, and the videos of the objects blue and green. We want to display these four word-object pairs in a random order, without replacement. We'll define one trial, then use a loop to run the remaining trials.

STEP 17
LET test_item = (TAKE test_trials RANDOM)
VIDEO CENTER test_item LOOP
AUDIO CENTER test_item LOOP
UNTIL TIME 14000
UNTIL SINGLELOOKAWAY test_item GREATERTHAN 1000

STEP 18
Trial End
VIDEO CENTER OFF
AUDIO CENTER OFF

The test phase is where we see the advantage of defining our pairs of tags via LINKED tags rather than selecting video and audio tags separately. If we had defined a test audio group and test video group, they would look like this:

LET test_audio = {deeb, deeb, geff, geff} LET test_video = {blue, green, blue, green}

With random selection from each in turn across trials, there would be nothing to stop us from repeating a pairing, and thus failing to show all the combinations of words and objects. For example, on our first test trial we could randomly select deeb and blue - but there is no way to specify that if we choose deeb again from the audio group, green must be selected rather than blue from the video group. We could define groups that would be chosen from in a fixed order, arranging each of the audio and video tags so that all the pairings are present when they are selected using FIRST (and creating multiple copies of this protocol to counterbalance test trial order.) But without LINKED tags, we could not use RANDOM selection in this protocol.

We'll use another loop to play the remaining three test trials, after our first one is done, and this concludes our test phase.

STEP 19
LOOP STEP 15
UNTIL 3 TIMES

STEP 20
Phase End

Post-test

Lastly, we have a post-test trial, which is identical to our pre-test phase.

STEP 21
Phase Posttest Start

STEP 22
LIGHT CENTER BLINK 250
UNTIL KEY C

STEP 23
LIGHT CENTER OFF
LET prepost2 = (TAKE prepost RANDOM)
Trial Start

STEP 24
VIDEO CENTER prepost LOOP
AUDIO CENTER prepost LOOP
UNTIL SINGLELOOKAWAY prepost GREATERTHAN 1000
UNTIL TIME 14000

STEP 11
Trial End
VIDEO CENTER OFF
AUDIO CENTER OFF

STEP 26
Phase End

Now our experiment is done!

See the resources page for a copy of this protocol.